1.1.1. Wat is het aantal cliënten per wet?

Concepten

• IndicatieBesluit
• Mens
• Vestiging
• Vestigingsnummer
• ZorgEnVerpleegProces

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: IGJ 1.1.1
2# Parameters: ?vestigingsnummer, ?peildatum
3# Ontologie: versie 3.0.0
4
5PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT 
12  ?aantal_uniek 
13  ?aantal_wlz
14  ?aantal_zvw
15  ?aantal_overig
16WHERE {
17  {
18    SELECT
19      ( SUM(?Wlz_uniek) AS ?aantal_wlz )
20      ( SUM(?Zvw_uniek) AS ?aantal_zvw )
21      ( COUNT(DISTINCT ?client) - SUM(?Wlz_uniek)- SUM(?Zvw_uniek)  AS ?aantal_overig )
22    WHERE {
23        {
24    SELECT 
25        ?client
26        (MAX(?Wlz) AS ?Wlz_uniek)
27        (MAX(?Zvw) AS ?Zvw_uniek)
28    WHERE {
29            # BIND($(vestigingsnummer) AS ?vestigingsnummer)
30            # BIND($(peildatum) AS ?peildatum)
31            BIND(?peildatum AS ?peildatum_argument)
32
33            # Nieuwe vestigingsnummer triple
34            ?vestiging 
35                a onz-org:Vestiging ;
36                onz-g:identifiedBy ?vestigingsnummer_object .
37            ?vestigingsnummer_object
38                a onz-org:Vestigingsnummer ;
39                onz-g:hasDataValue ?vestigingsnummer .
40
41            ?subtype_indicatie rdfs:subClassOf onz-zorg:IndicatieBesluit . 
42            ?client a onz-g:Human .
43
44            #selecteer de bijbehorende indicatie, om unieke clienten te kunnen bepalen
45            ?indicatie 
46                a ?subtype_indicatie ;
47                onz-g:startDatum ?start_indicatie ;
48                onz-g:isAbout ?client .
49            OPTIONAL {?indicatie onz-g:eindDatum ?eind_indicatie}
50            FILTER(?peildatum_argument >= ?start_indicatie && (?peildatum_argument <= ?eind_indicatie || !BOUND(?eind_indicatie)))
51            # FILTER(?peildatum >= ?start_indicatie && (?peildatum <= ?eind_indicatie || !BOUND(?eind_indicatie)))
52            
53            #selecteer de zorgprocessen die voldoen aan de inclusiecriteria
54            ?zorgproces
55                a onz-g:CureAndCareProcess ;
56                onz-g:definedBy ?indicatie ;
57                onz-g:hasPerdurantLocation/onz-g:partOf* ?vestiging ;
58                onz-g:startDatum ?start_zorgproces .
59                OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
60                FILTER (?start_zorgproces <= ?peildatum_argument && ((?eind_zorgproces >= ?peildatum_argument)||(!BOUND(?eind_zorgproces))))
61                #FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum)||(!BOUND(?eind_zorgproces))))
62
63            #Per financieringsstroom
64            BIND(IF(?subtype_indicatie = onz-zorg:WlzIndicatie, 1, 0) AS ?Wlz)
65            BIND(IF(?subtype_indicatie = onz-zorg:ZvwIndicatie, 1, 0) AS ?Zvw)
66            } 
67            GROUP BY ?client
68        }
69      }
70    }
71    BIND(?aantal_wlz + ?aantal_zvw + ?aantal_overig AS ?aantal_uniek)
72}